package flashx.textLayout.conversion.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.conversion.ConversionType;
    import flashx.textLayout.conversion.PlainTextExporter;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.elements.TextFlow;

    public class PlainTextExporter_example extends Sprite
    {
        public function PlainTextExporter_example()
        {
            var markup:String = "<TextFlow xmlns='http://ns.adobe.com/textLayout/2008'>" + 
                    "<p><span>Hello, World!</span></p>" + 
                    "<p><span>Hello, Hemi" + "\u00AD" + "sphere! </span></p>" +
                    "<p><span>Hello, Hello Continent!</span></p>" +
                    "</TextFlow>";

            var textFlow:TextFlow = TextConverter.importToFlow(markup, TextConverter.TEXT_LAYOUT_FORMAT);
            
            // first export, using the PlainTextExporter class
            var textExporter:PlainTextExporter = new PlainTextExporter();
            var exportedText:String = textExporter.export(textFlow, flashx.textLayout.conversion.ConversionType.STRING_TYPE) as String;
            
            // second export, using TextConverter.export() static method is same as first export with default settings
            var exportedTextTextConverter:String = TextConverter.export(textFlow,TextConverter.PLAIN_TEXT_FORMAT, ConversionType.STRING_TYPE) as String;
            
            // use of PlainTextExporter class allows for custom control of paragraph separators and hyphen interpretation
            // third export, we change the paragraph separator to a carriage return and linefeed combination
            textExporter.paragraphSeparator = "\r\n";
            exportedText = textExporter.export(textFlow, flashx.textLayout.conversion.ConversionType.STRING_TYPE) as String;
            
            // Discretionary hyphen characters are stripped by default.
            // fourth export, we retain discretionary hyphens by setting the stripDiscretionaryHyphens property to false
            textExporter.stripDiscretionaryHyphens = false;
            var exportedTextWithHyphens:String = textExporter.export(textFlow, flashx.textLayout.conversion.ConversionType.STRING_TYPE) as String;
            
            // The following should report false after setting stripDiscretionaryHyphens to false
            var bothExportStringsHaveHyphens:Boolean = (exportedText == exportedTextWithHyphens);
        }
    }
}