Contains the reference number associated with the specific error message. For a custom Error object, this number is the value from the id parameter supplied in the constructor.

Contains the message associated with the Error object. By default, the value of this property is "Error". You can specify a message property when you create an Error object by passing the error string to the Error constructor function.

Related API Elements

Contains the name of the Error object. By default, the value of this property is "Error".

Related API Elements

Creates a new Error object. If message is specified, its value is assigned to the object's Error.message property.

Related API Elements

var err:Error = new Error();
trace(err.toString());    // Error

err = new Error("New Error Message");
trace(err.toString());    // Error: New Error Message

Returns the call stack for an error as a string at the time of the error's construction (for the debugger version of Flash Player and the AIR Debug Launcher (ADL) only; returns null if not using the debugger version of Flash Player or the ADL. As shown in the following example, the first line of the return value is the string representation of the exception object, followed by the stack trace elements:

     TypeError: null cannot be converted to an object
         at com.xyz.OrderEntry.retrieveData(OrderEntry.as:995)
         at com.xyz.OrderEntry.init(OrderEntry.as:200)
         at com.xyz.OrderEntry.$construct(OrderEntry.as:148)
        

Returns the string "Error" by default or the value contained in the Error.message property, if defined.

Related API Elements

var err:Error = new Error();
trace(err.toString());    // Error

err = new Error("New Error Message");
trace(err.toString());    // Error: New Error Message

err.message = "Another New Error Message";
trace(err.toString());    // Error: Another New Error Message

1. A local variable nullArray of Array type is declared, but notice that a new Array object is never created.
2. The constructor attempts to load a value into the uninitialized array by using the push() method within an error handling code segment that catches a custom error by using the CustomError class, which extends Error.
3. When the CustomError is thrown, the constructor catches it and then outputs an error message by using the trace() statement.

package
{
    import flash.display.Sprite;
    public class ErrorExample extends Sprite 
    {
        private var nullArray:Array;
        public function ErrorExample() 
        {
            try 
            {
                nullArray.push("item");
            }
            catch(e:Error) 
            {
                throw new CustomError("nullArray is null");
            }
        }
    }
}

class CustomError extends Error 
{
    public function CustomError(message:String) 
    {
        super(message);
    }
}