package flashx.textLayout.formats.examples {
    import flash.display.Sprite;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextAlign;
    import flashx.textLayout.formats.TextJustify;

    public class TextAlignExample extends Sprite
    {
        public function TextAlignExample()
        {
            var textFlow:TextFlow = new TextFlow();
            //create paragraphs and corresponding spans
            var pCenter:ParagraphElement = new ParagraphElement();
            var pJustify:ParagraphElement = new ParagraphElement();
            var pRight:ParagraphElement = new ParagraphElement();    
            var spanCenter:SpanElement = new SpanElement();
            var spanJustify:SpanElement = new SpanElement();
            var spanRight:SpanElement = new SpanElement();
            // add text to the spans
            spanCenter.text = "Hello, World\n";
            spanJustify.text = "Hello, World\n";
            spanRight.text = "Hello, World";
            // add spans to paragraphs and specify alignment
            pCenter.addChild(spanCenter);
            pCenter.textAlign = TextAlign.CENTER;
            
            pJustify.addChild(spanJustify);
            pJustify.textAlign = TextAlign.JUSTIFY;
            pJustify.textJustify = TextJustify.DISTRIBUTE;
                    
            pRight.addChild(spanRight);
            pRight.textAlign = TextAlign.RIGHT;
            // add paragraphs to TextFlow
            textFlow.addChild(pCenter);
            textFlow.addChild(pJustify);
            textFlow.addChild(pRight);
            // update controller to display
            textFlow.flowComposer.addController(new ContainerController(this,80,800));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}