package flashx.textLayout.events.examples {
    import flash.display.Sprite;
    import flash.events.Event;
    
    import flashx.textLayout.compose.StandardFlowComposer;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.events.TextLayoutEvent;
    import flashx.undo.UndoManager;
    
    public class TextLayoutEvent_example extends Sprite
    {        
        private const textMarkup:String = "<flow:TextFlow xmlns:flow='http://ns.adobe.com/textLayout/2008' fontSize='14' " + 
            "textIndent='10' paragraphSpaceBefore='6' paddingTop='8' paddingLeft='8' paddingRight='8'>" +
            "<flow:p paragraphSpaceBefore='inherit'>" +
                "<flow:span>There are many </flow:span>" + 
                "<flow:span fontStyle='italic'>such</flow:span>" + 
                "<flow:span> lime-kilns in that tract of country, for the purpose of burning the white" + 
                    " marble which composes a large part of the substance of the hills. Some of them, built " + 
                    "years ago, and long deserted, with weeds growing in the vacant round of the interior, " + 
                    "which is open to the sky, and grass and wild-flowers rooting themselves into the chinks" + 
                    "of the stones, look already like relics of antiquity, and may yet be overspread with the" + 
                    " lichens of centuries to come. Others, where the lime-burner still feeds his daily and " + 
                    "nightlong fire, afford points of interest to the wanderer among the hills, who seats " + 
                    "himself on a log of wood or a fragment of marble, to hold a chat with the solitary man. " + 
                    "It is a lonesome, and, when the character is inclined to thought, may be an intensely " + 
                    "thoughtful occupation; as it proved in the case of Ethan Brand, who had mused to such " + 
                    "strange purpose, in days gone by, while the fire in this very kiln was burning.</flow:span>" +
            "</flow:p>" +
            "</flow:TextFlow>";
        
        public function TextLayoutEvent_example()
        {
            // create the TextFlow, container, and container controller
            var textFlow:TextFlow;
            var container:Sprite = new Sprite();
            var _controller:ContainerController = new ContainerController(container, 200, 100);
            
            // import the text flow from markup using TextFilter and assign a StandardFlowComposer
            textFlow = TextConverter.importToFlow(textMarkup, TextConverter.TEXT_LAYOUT_FORMAT);
            textFlow.flowComposer = new StandardFlowComposer();
            
            // create undo, edit and interaction managers
            var _undoManager:UndoManager = new UndoManager();
            var _editManager:EditManager = new EditManager(_undoManager);
            textFlow.interactionManager = _editManager;
            
            // Add container to display list
            addChild(container);
            container.x = 25;
            container.y = 100;
            
            // Add an event listener for the TextLayoutEvent.SCROLL event
            textFlow.addEventListener(TextLayoutEvent.SCROLL, scrollEventHandler);
            
            // add the controller to the text flow and update it to display the text
            textFlow.flowComposer.addController(_controller);
            textFlow.flowComposer.updateAllControllers();
        }
        
        private function scrollEventHandler(evt:Event):void {
            trace ("scroll event occurred");
        }
    }
}