flashx.textLayout.edit.IEditManager - Adobe® Flex® 4 Language Reference (Flex 4)

Package	flashx.textLayout.edit
Interface	public interface IEditManager extends ISelectionManager , IInteractionEventHandler
Implementors	EditManager

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

IEditManager defines the interface for handling edit operations of a text flow.

To enable text flow editing, assign an IEditManager instance to the interactionManager property of the TextFlow object. The edit manager handles changes to the text (such as insertions, deletions, and format changes). Changes are reversible if the edit manager has an undo manager. The edit manager triggers the recomposition and display of the text flow, as necessary.

Public Properties

Hide Inherited Public Properties

Show Inherited Public Properties

	Property		Defined By
		absoluteEnd : int [read-only] The text position of the end of the selection, as an offset from the start of the text flow.	ISelectionManager
		absoluteStart : int [read-only] The text position of the start of the selection, as an offset from the start of the text flow.	ISelectionManager
		activePosition : int [read-only] The active point of the selection.	ISelectionManager
		anchorPosition : int [read-only] The anchor point of the selection.	ISelectionManager
		currentSelectionFormat : SelectionFormat [read-only] The current SelectionFormat object.	ISelectionManager
		editingMode : String [read-only] The editing mode.	ISelectionManager
		focused : Boolean [read-only] Indicates whether a container in the text flow has the focus.	ISelectionManager
		focusedSelectionFormat : SelectionFormat The SelectionFormat object used to draw the selection in a focused container.	ISelectionManager
		inactiveSelectionFormat : SelectionFormat The SelectionFormat object used to draw the selection when it is not in the active window.	ISelectionManager
		textFlow : flashx.textLayout.elements:TextFlow The TextFlow object managed by this selection manager.	ISelectionManager
		undoManager : IUndoManager [read-only] The UndoManager object assigned to this EditManager instance, if there is one.	IEditManager
		unfocusedSelectionFormat : SelectionFormat The SelectionFormat object used to draw the selection when it is not in a focused container, but is in the active window.	ISelectionManager
		windowActive : Boolean [read-only] Indicates whether the window associated with the text flow is active.	ISelectionManager

Public Methods

Hide Inherited Public Methods

Show Inherited Public Methods

	Method		Defined By
		activateHandler(event:Event):void Processes an activate event.	IInteractionEventHandler
		applyContainerFormat(format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Applies container styles to any containers in the selection.	IEditManager
		applyFormat(leafFormat:flashx.textLayout.formats:ITextLayoutFormat, paragraphFormat:flashx.textLayout.formats:ITextLayoutFormat, containerFormat:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Changes the formats of the specified (or current) selection.	IEditManager
		applyFormatToElement(targetElement:FlowElement, format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Applies styles to the specified element.	IEditManager
		applyLeafFormat(format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Changes the format applied to the leaf elements in the specified (or current) selection.	IEditManager
		applyLink(href:String, target:String = null, extendToLinkBoundary:Boolean = false, operationState:SelectionState = null):void Transforms a selection into a link, or a link into normal text.	IEditManager
		applyParagraphFormat(format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Applies paragraph styles to any paragraphs in the selection.	IEditManager
		applyTCY(tcyOn:Boolean, operationState:SelectionState = null):void Transforms text into a TCY run, or a TCY run into non-TCY text.	IEditManager
		beginCompositeOperation():void Begins a new group of operations.	IEditManager
		changeElementID(newID:String, targetElement:FlowElement, relativeStart:int = 0, relativeEnd:int = -1, operationState:SelectionState = null):void Changes the ID of an element.	IEditManager
		changeStyleName(newName:String, targetElement:FlowElement, relativeStart:int = 0, relativeEnd:int = -1, operationState:SelectionState = null):void Changes the styleName of an element or part of an element.	IEditManager
		clearFormat(leafFormat:flashx.textLayout.formats:ITextLayoutFormat, paragraphFormat:flashx.textLayout.formats:ITextLayoutFormat, containerFormat:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Undefines formats of the specified (or current) selection.	IEditManager
		clearFormatOnElement(targetElement:FlowElement, format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void Undefines styles to the specified element.	IEditManager
		cutTextScrap(operationState:SelectionState = null):flashx.textLayout.edit:TextScrap Deletes the selected area and returns the deleted area in a TextScrap object.	IEditManager
		deactivateHandler(event:Event):void Processes a deactivate event.	IInteractionEventHandler
		deleteNextCharacter(operationState:SelectionState = null):void Deletes a range of text, or, if a point selection is given, deletes the next character.	IEditManager
		deleteNextWord(operationState:SelectionState = null):void Deletes the next word.	IEditManager
		deletePreviousCharacter(operationState:SelectionState = null):void Deletes a range of text, or, if a point selection is given, deletes the previous character.	IEditManager
		deletePreviousWord(operationState:SelectionState = null):void Deletes the previous word.	IEditManager
		deleteText(operationState:SelectionState = null):void Deletes a range of text.	IEditManager
		doOperation(operation:FlowOperation):void Executes a FlowOperation.	IEditManager
		editHandler(event:Event):void Processes an edit event.	IInteractionEventHandler
		endCompositeOperation():void Ends a group of operations.	IEditManager
		flushPendingOperations():void Executes any pending FlowOperations.	ISelectionManager
		focusChangeHandler(event:FocusEvent):void Processes a focusChange event.	IInteractionEventHandler
		focusInHandler(event:FocusEvent):void Processes a focusIn event.	IInteractionEventHandler
		focusOutHandler(event:FocusEvent):void Processes a focusOut event.	IInteractionEventHandler
		getCommonCharacterFormat(range:flashx.textLayout.elements:TextRange = null):flashx.textLayout.formats:ITextLayoutFormat Gets the character format attributes that are common to all characters in the specified text range or current selection.	ISelectionManager
		getCommonContainerFormat(range:flashx.textLayout.elements:TextRange = null):flashx.textLayout.formats:ITextLayoutFormat Gets the container format attributes that are common to all containers in the specified text range or current selection.	ISelectionManager
		getCommonParagraphFormat(range:flashx.textLayout.elements:TextRange = null):flashx.textLayout.formats:ITextLayoutFormat Gets the paragraph format attributes that are common to all paragraphs in the specified text range or current selection.	ISelectionManager
		getSelectionState():SelectionState Gets the SelectionState object of the current selection.	ISelectionManager
		hasSelection():Boolean Indicates whether there is a selection.	ISelectionManager
		imeStartCompositionHandler(event:IMEEvent):void Processes an imeStartComposition event	IInteractionEventHandler
		insertInlineGraphic(source:Object, width:Object, height:Object, options:Object = null, operationState:SelectionState = null):void Inserts an image.	IEditManager
		insertText(text:String, operationState:SelectionState = null):void Inserts text.	IEditManager
		isRangeSelection():Boolean Indicates whether the selection covers a range of text.	ISelectionManager
		keyDownHandler(event:KeyboardEvent):void Processes a keyDown event.	IInteractionEventHandler
		keyFocusChangeHandler(event:FocusEvent):void Processes a keyFocusChange event.	IInteractionEventHandler
		keyUpHandler(event:KeyboardEvent):void Processes a keyUp event.	IInteractionEventHandler
		menuSelectHandler(event:ContextMenuEvent):void Processes a menuSelect event.	IInteractionEventHandler
		modifyInlineGraphic(source:Object, width:Object, height:Object, options:Object = null, operationState:SelectionState = null):void Modifies an existing inline graphic.	IEditManager
		mouseDoubleClickHandler(event:MouseEvent):void Processes a mouseDoubleClick event.	IInteractionEventHandler
		mouseDownHandler(event:MouseEvent):void Processes a mouseDown event.	IInteractionEventHandler
		mouseMoveHandler(event:MouseEvent):void Processes a mouseMove event.	IInteractionEventHandler
		mouseOutHandler(event:MouseEvent):void Processes a mouseOut event.	IInteractionEventHandler
		mouseOverHandler(event:MouseEvent):void Processes a mouseOver event.	IInteractionEventHandler
		mouseUpHandler(event:MouseEvent):void Processes a mouseUp event.	IInteractionEventHandler
		mouseWheelHandler(event:MouseEvent):void Processes a mouseWheel event.	IInteractionEventHandler
		notifyInsertOrDelete(absolutePosition:int, length:int):void Updates the selection manager when text is inserted or deleted.	ISelectionManager
		overwriteText(text:String, operationState:SelectionState = null):void Overwrites the selected text.	IEditManager
		pasteTextScrap(scrapToPaste:flashx.textLayout.edit:TextScrap, operationState:SelectionState = null):void Pastes the TextScrap into the selected area.	IEditManager
		redo():void Reperforms the previous undone operation.	IEditManager
		refreshSelection():void Redisplays the selection shapes.	ISelectionManager
		selectAll():void Selects the entire flow	ISelectionManager
		selectRange(anchorPosition:int, activePosition:int):void Selects a range of text.	ISelectionManager
		setFocus():void Gives the focus to the first container in the selection.	ISelectionManager
		setSelectionState(state:SelectionState):void Sets the SelectionState object of the current selection.	ISelectionManager
		splitParagraph(operationState:SelectionState = null):void Splits the paragraph at the current position.	IEditManager
		textInputHandler(event:flash.events:TextEvent):void Processes a TextEvent.	IInteractionEventHandler
		undo():void Reverses the previous operation.	IEditManager

Property Detail

undoManager

property

undoManager:IUndoManager [read-only]

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

The UndoManager object assigned to this EditManager instance, if there is one.

An undo manager handles undo and redo operations.

Implementation
public function get undoManager():IUndoManager

Method Detail

applyContainerFormat

()

method

 public function applyContainerFormat(format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Applies container styles to any containers in the selection.

Any style properties in the format object that are null are left unchanged.

Parameters

	`format:flashx.textLayout.formats:ITextLayoutFormat` — the format to apply to the containers in the range

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example changes the format of the containers holding a selection to display two columns:

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class EditManager_applyContainerFormat
    {
        public function EditManager_applyContainerFormat( selection:SelectionState ):void
         {
             var textFlow:TextFlow = selection.textFlow;
             var editManager:IEditManager = textFlow.interactionManager as IEditManager;
             
             var containerStyle:TextLayoutFormat = new TextLayoutFormat();
             containerStyle.columnCount = 2;
             
             editManager.applyContainerFormat( containerStyle );
         }    
    }
}

applyFormat

()

method

 public function applyFormat(leafFormat:flashx.textLayout.formats:ITextLayoutFormat, paragraphFormat:flashx.textLayout.formats:ITextLayoutFormat, containerFormat:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Changes the formats of the specified (or current) selection.

Executes an undoable operation that applies the new formats. Only style attributes set for the TextLayoutFormat objects are applied. Undefined attributes in the format objects are not changed.

Parameters

	`leafFormat:flashx.textLayout.formats:ITextLayoutFormat` — the format to apply to leaf elements such as spans and inline graphics

	`paragraphFormat:flashx.textLayout.formats:ITextLayoutFormat` — format to apply to paragraph elements

	`containerFormat:flashx.textLayout.formats:ITextLayoutFormat` — format to apply to the containers

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example applies a container, paragraph, and a character format to a selection.

 
package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextAlign;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class EditManager_applyFormat
    {
        public function EditManager_applyFormat( selection:SelectionState ):void
        {
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
         
            var containerStyle:TextLayoutFormat = new TextLayoutFormat();
            containerStyle.columnCount = 2;
            
            var paraStyle:TextLayoutFormat = new TextLayoutFormat();
            paraStyle.textAlign = TextAlign.JUSTIFY;
            
            var charStyle:TextLayoutFormat = new TextLayoutFormat();
            charStyle.color = 0xff0000;
            
            editManager.applyFormat( charStyle, paraStyle, containerStyle );    
        }
    }
}

applyFormatToElement

()

method

 public function applyFormatToElement(targetElement:FlowElement, format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Applies styles to the specified element.

Any style properties in the format object that are null are left unchanged. Only styles that are relevant to the specified element are applied.

Parameters

	`targetElement:FlowElement` — the element to which the styles are applied.

	`format:flashx.textLayout.formats:ITextLayoutFormat` — the format containing the styles to apply

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example applies a format to a <div> element in the mid-level of the flow element hierarchy.


package flashx.textLayout.edit.examples
{
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.FlowElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class EditManager_applyFormatToElement
    {
        public function EditManager_applyFormatToElement( selection:SelectionState ):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow("<TextFlow><div><p><span>Hello World</span></p></div><p>No indent</p></TextFlow>", TextConverter.TEXT_LAYOUT_FORMAT);
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
            var divElement:FlowElement = textFlow.getChildAt(0);
            
            var format:TextLayoutFormat = new TextLayoutFormat();
            format.textIndent = 15;
            
            
            editManager.applyFormatToElement( divElement, format );    
        }
    }
}

applyLeafFormat

()

method

 public function applyLeafFormat(format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Changes the format applied to the leaf elements in the specified (or current) selection.

Executes an undoable operation that applies the new format to leaf elements such as SpanElement and InlineGraphicElement objects. Only style attributes set for the TextLayoutFormat objects are applied. Undefined attributes in the format object are changed.

Parameters

	`format:flashx.textLayout.formats:ITextLayoutFormat` — the format to apply.

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example changes the color of text in a selection to red.

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class EditManager_applyLeafFormat
    {
        public function EditManager_applyLeafFormat(selection:SelectionState)
        {
             var textFlow:TextFlow = selection.textFlow;
             var editManager:IEditManager = textFlow.interactionManager as IEditManager;
        
             var charStyle:TextLayoutFormat = new TextLayoutFormat();
             charStyle.color = 0xff0000;
             
             editManager.applyLeafFormat( charStyle );    
        }
    }
}

applyLink

()

method

 public function applyLink(href:String, target:String = null, extendToLinkBoundary:Boolean = false, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Transforms a selection into a link, or a link into normal text.

Executes an undoable operation that creates or removes the link.

If a target parameter is specified, it must be one of the following values:

"_self"
"_blank"
"_parent"
"_top"

In browser-hosted runtimes, a target of "_self" replaces the current html page. So, if the SWF content containing the link is in a page within a frame or frameset, the linked content loads within that frame. If the page is at the top level, the linked content opens to replace the original page. A target of "_blank" opens a new browser window with no name. A target of "_parent" replaces the parent of the html page containing the SWF content. A target of "_top" replaces the top-level page in the current browser window.

In other runtimes, such as Adobe AIR, the link opens in the user's default browser and the target parameter is ignored.

The extendToLinkBoundary parameter determines how the edit manager treats a selection that intersects with one or more existing links. If the parameter is true, then the operation is applied as a unit to the selection and the whole text of the existing links. Thus, a single link is created that spans from the beginning of the first link intersected to the end of the last link intersected. In contrast, if extendToLinkBoundary were false in this situation, the existing partially selected links would be split into two links.

Parameters

	`href:String` — The uri referenced by the link.

	`target:String` (default = `null`) — The target browser window of the link.

	`extendToLinkBoundary:Boolean` (default = `false`) — Specifies whether to consolidate selection with any overlapping existing links, and then apply the change.

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

See also

flashx.textLayout.elements.LinkElement

Example ( How to use this example )

The following example defines two functions. The first transforms a selection into a link. The second removes the URL from a link.

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_applyLink
    {
        
        static public function makeLink( selection:SelectionState ):void
         {
             var textFlow:TextFlow = selection.textFlow;
             var editManager:IEditManager = textFlow.interactionManager as IEditManager;
                 
             editManager.applyLink( "http://www.adobe.com" );
         }
         
        static public function removeLink( selection:SelectionState ):void
         {
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
            
            editManager.applyLink( null, null, true );    
         }
    }
}

applyParagraphFormat

()

method

 public function applyParagraphFormat(format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Applies paragraph styles to any paragraphs in the selection.

Any style properties in the format object that are null are left unchanged.

Parameters

	`format:flashx.textLayout.formats:ITextLayoutFormat` — the format to apply to the selected paragraphs.

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example defines a function to change the format of any paragraphs included in a current selection to justify the text.

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextAlign;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class EditManager_applyParagraphFormat
    {
        static public function justifyParagraph( selection:SelectionState ):void
         {
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
         
             var paraStyle:TextLayoutFormat = new TextLayoutFormat();
             paraStyle.textAlign = TextAlign.JUSTIFY;
         
             editManager.applyParagraphFormat( paraStyle );    
         }
    }
}

applyTCY

()

method

public function applyTCY(tcyOn:Boolean, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Transforms text into a TCY run, or a TCY run into non-TCY text.

TCY, or tate-chu-yoko, causes text to draw horizontally within a vertical line, and is used to make small blocks of non-Japanese text or numbers, such as dates, more readable in vertical text.

Parameters

	`tcyOn:Boolean` — specify `true` to apply TCY to a text range, `false` to remove TCY.

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

See also

flashx.textLayout.elements.TCYElement

Example ( How to use this example )

The following example defines two functions. The first applies TCY formatting to the current selection. The second removes TCY formatting.

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_applyTCY
    {
        static public function tcyOn( selection:SelectionState ):void
         {
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
        
             editManager.applyTCY( true );
         }
         
        static public function tcyOff( selection:SelectionState ):void
         {
        
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
        
             editManager.applyTCY( false );    
         }
    }
}

beginCompositeOperation

()

method

public function beginCompositeOperation():void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Begins a new group of operations.

All operations executed after the call to beginCompositeOperation(), and before the matching call to endCompositeOperation() are executed and grouped together as a single operation that can be undone as a unit.

A beginCompositeOperation/endCompositeOperation block can be nested inside another beginCompositeOperation/endCompositeOperation block.

See also

flashx.textLayout.edit.IEditManager.endCompositeOperation

Example ( How to use this example )

The following example defines a function that inserts a graphic object in its own paragraph. If the beginCompositeOperation() and endCompositeOperation() functions were not used, then each of the suboperations would have to be undone separately rather than as a group.

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_beginCompositeOperation
    {
        static public function insertGraphic( source:Object, width:Object, height:Object, float:String, selection:SelectionState ):void
        {
            var editManager:IEditManager = selection.textFlow.interactionManager as IEditManager;
            
            editManager.beginCompositeOperation();
            
            editManager.deleteText( selection );
            var changedSelection:SelectionState = 
                new SelectionState( selection.textFlow, selection.anchorPosition, selection.anchorPosition );
            editManager.splitParagraph( changedSelection );
            changedSelection = 
                new SelectionState( changedSelection.textFlow, changedSelection.anchorPosition + 1, changedSelection.anchorPosition + 1);
            editManager.insertInlineGraphic( source, width, height, float, changedSelection );
            changedSelection = 
                new SelectionState( changedSelection.textFlow, changedSelection.anchorPosition + 1, changedSelection.anchorPosition + 1);
            editManager.splitParagraph( changedSelection );
            
            editManager.endCompositeOperation();                
        }
    }
}

changeElementID

()

method

 public function changeElementID(newID:String, targetElement:FlowElement, relativeStart:int = 0, relativeEnd:int = -1, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Changes the ID of an element.

If the relativeStart or relativeEnd parameters are set (to anything other than the default values), then the element is split. The parts of the element outside this range retain the original ID. Setting both the relativeStart and relativeEnd parameters creates elements with duplicate IDs.

Parameters

	`newID:String` — the new ID value

	`targetElement:FlowElement` — the element to modify

	`relativeStart:int` (default = `0`) — an offset from the beginning of the element at which to split the element when assigning the new ID

	`relativeEnd:int` (default = `-1`) — an offset from the end of the element at which to split the element when assigning the new ID

	`operationState:SelectionState` (default = `null`) — specifies the selection to restore when undoing this operation; if `null`, the operation saves the current selection.

Example ( How to use this example )

The following example defines a function that changes the ID of the first paragraph in a selection:

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.ElementRange;
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_changeElementID
    {
        static public function changeParagraphID( id:String, selection:SelectionState ):void
         {
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
            var selectedRange:ElementRange = ElementRange.createElementRange( selection.textFlow, selection.absoluteStart, selection.absoluteEnd );            
        
            editManager.changeElementID( id, selectedRange.firstParagraph, 0, -1, selection );    
         }
    }
}

changeStyleName

()

method

 public function changeStyleName(newName:String, targetElement:FlowElement, relativeStart:int = 0, relativeEnd:int = -1, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Changes the styleName of an element or part of an element.

Parameters

	`newName:String` — the name of the new style.

	`targetElement:FlowElement` — specifies the element to change.

	`relativeStart:int` (default = `0`) — an offset from the beginning of the element at which to split the element when assigning the new style

	`relativeEnd:int` (default = `-1`) — an offset from the end of the element at which to split the element when assigning the new style

	`operationState:SelectionState` (default = `null`) — specifies the selection to restore when undoing this operation; if `null`, the operation saves the current selection.

Example ( How to use this example )

The following example defines a functions that changes the style name of the first paragraph in a selection:

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.ElementRange;
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_changeStyleName
    {
        static public function changeParagraphStyle( styleName:String, selection:SelectionState ):void
        {
            var textFlow:TextFlow = selection.textFlow;
            var editManager:IEditManager = textFlow.interactionManager as IEditManager;
            var selectedRange:ElementRange = ElementRange.createElementRange( selection.textFlow, selection.absoluteStart, selection.absoluteEnd );            
        
            editManager.changeElementID( styleName, selectedRange.firstParagraph, 0, -1, selection );    
        }
    }
}

clearFormat

()

method

 public function clearFormat(leafFormat:flashx.textLayout.formats:ITextLayoutFormat, paragraphFormat:flashx.textLayout.formats:ITextLayoutFormat, containerFormat:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Undefines formats of the specified (or current) selection.

Executes an undoable operation that undefines the specified formats. Only style attributes set for the TextLayoutFormat objects are applied. Undefined attributes in the format objects are not changed.

Parameters

	`leafFormat:flashx.textLayout.formats:ITextLayoutFormat` — The format whose set values indicate properties to undefine to LeafFlowElement objects in the selected range.

	`paragraphFormat:flashx.textLayout.formats:ITextLayoutFormat` — The format whose set values indicate properties to undefine to ParagraphElement objects in the selected range.

	`containerFormat:flashx.textLayout.formats:ITextLayoutFormat` — The format whose set values indicate properties to undefine to ContainerController objects in the selected range.

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

clearFormatOnElement

()

method

 public function clearFormatOnElement(targetElement:FlowElement, format:flashx.textLayout.formats:ITextLayoutFormat, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Undefines styles to the specified element.

Any style properties in the format object that are undefined are left unchanged. Any styles that are defined in the specififed format are undefined on the specified element.

Parameters

	`targetElement:FlowElement` — the element to which the styles are applied.

	`format:flashx.textLayout.formats:ITextLayoutFormat` — the format containing the styles to undefine

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

cutTextScrap

()

method

public function cutTextScrap(operationState:SelectionState = null):flashx.textLayout.edit:TextScrap

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Deletes the selected area and returns the deleted area in a TextScrap object.

The resulting TextScrap can be posted to the system clipboard or used in a subsequent pasteTextOperation() operation.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Returns

flashx.textLayout.edit:TextScrap — the TextScrap that was cut

See also

flashx.textLayout.edit.IEditManager.pasteTextScrap
flashx.textLayout.edit.TextClipboard.setContents

Example ( How to use this example )

The following example creates a selection in a text flow cuts the selected range and creates a TextScrap object containing the deleted content.

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.edit.TextScrap;
    import flashx.undo.UndoManager;
    import flashx.textLayout.elements.TextFlow;

    public class EditManager_cutTextScrap
    {
        static public function cutTextScrap():TextScrap
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How do now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( new Sprite() ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 4, 7 );
            var scrap:TextScrap = editManager.cutTextScrap(); //Displays: How now brown cow.
            return scrap;
        }
    }
}

deleteNextCharacter

()

method

public function deleteNextCharacter(operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Deletes a range of text, or, if a point selection is given, deletes the next character.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Example ( How to use this example )

The following example creates a point selection in a text flow and deletes the next character.

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_deleteNextCharacter
    {
        static public function deleteNextCharacter():void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How now brown crow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( new Sprite() ));
            var editManager:EditManager = new EditManager();
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 15, 15 );
            editManager.deleteNextCharacter(); //displays: How now brown cow.
        }
    }
}

deleteNextWord

()

method

public function deleteNextWord(operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Deletes the next word.

If a range is selected, the first word of the range is deleted.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Example ( How to use this example )

The following example creates a point selection in a text flow and deletes the next word.

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_deleteNextWord
    {
        static public function deleteNextWord():void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How do now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( new Sprite() ));
            var editManager:EditManager = new EditManager();
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 3, 3 );
            editManager.deleteNextWord(); //displays: How now brown cow.
        }
    }
}

deletePreviousCharacter

()

method

public function deletePreviousCharacter(operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Deletes a range of text, or, if a point selection is given, deletes the previous character.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Example ( How to use this example )

The following example creates a point selection in a text flow and deletes the previous character.

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_deletePreviousCharacter
    {
        
        static public function deletePreviousCharacter():void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How now brown crow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( new Sprite() ));
            var editManager:EditManager = new EditManager();
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 16, 16 );
            editManager.deletePreviousCharacter(); //displays: How now brown cow.
        }
    }
}

deletePreviousWord

()

method

public function deletePreviousWord(operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Deletes the previous word.

If a range is selected, the first word of the range is deleted.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Example ( How to use this example )

The following example creates a point selection in a text flow and deletes the previous word.

var textFlow:TextFlow = TextConverter.importToFlow( "How do now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
textFlow.flowComposer = new StandardFlowComposer();
textFlow.flowComposer.addController( new ContainerController( this ));
var editManager:EditManager = new EditManager( new UndoManager() );
textFlow.interactionManager = editManager;
textFlow.flowComposer.updateAllControllers();

editManager.setSelection( 7, 7 );
editManager.deletePreviousWord(); //displays: How now brown cow.

deleteText

()

method

public function deleteText(operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Deletes a range of text.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Example ( How to use this example )

The following example creates a range selection in a text flow and deletes the selected characters.

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_deleteText
    {
        static public function deleteText():void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How do now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( new Sprite() ));
            var editManager:EditManager = new EditManager();
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 4, 7 );
            editManager.deleteText(); //displays: How now brown cow.
        }
    }
}

doOperation

()

method

public function doOperation(operation:FlowOperation):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Executes a FlowOperation.

The doOperation() method is called by IEditManager functions that update the text flow. You do not typically need to call this function directly unless you create your own custom operations.

This function proceeds in the following steps:

Flush any pending operations before performing this operation.
Send a cancelable flowOperationBegin event. If canceled this method returns immediately.
Execute the operation. The operation returns true or false. False indicates that no changes were made.
Push the operation onto the undo stack.
Clear the redo stack.
Update the display.
Send a cancelable flowOperationEnd event.

Exception handling: If the operation throws an exception, it is caught and the error is attached to the flowOperationEnd event. If the event is not canceled the error is rethrown.

Parameters

operation:FlowOperation — a FlowOperation object

Example ( How to use this example )

The following example creates and executes an InsertTextOperation:

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.edit.SelectionState;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.operations.InsertTextOperation;
    
    public class EditManager_doOperation
    {
        static public function doOperation(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager();
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            var selectionState:SelectionState = new SelectionState(textFlow, 4, 4);            
            var insertOperation:InsertTextOperation = new InsertTextOperation( selectionState, "now " );
            editManager.doOperation( insertOperation );        // displays: How now brown cow
        }
    }
}

endCompositeOperation

()

method

public function endCompositeOperation():void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Ends a group of operations.

All operations executed since the last call to beginCompositeOperation() are grouped as a CompositeOperation that is then completed. This CompositeOperation object is added to the undo stack or, if this composite operation is nested inside another composite operation, added to the parent operation.

See also

flashx.textLayout.edit.IEditManager.beginCompositeOperation

insertInlineGraphic

()

method

 public function insertInlineGraphic(source:Object, width:Object, height:Object, options:Object = null, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Inserts an image.

The source of the image can be a string containing a URI, URLRequest object, a Class object representing an embedded asset, or a DisplayObject instance.

The width and height values can be the number of pixels, a percent, or the string, 'auto', in which case the actual dimension of the graphic is used.

Set the float to one of the constants defined in the Float class to specify whether the image should be displayed to the left or right of any text or inline with the text.

Parameters

	`source:Object` — can be either a String interpreted as a uri, a Class interpreted as the class of an Embed DisplayObject, a DisplayObject instance or a URLRequest.

	`width:Object` — width of the image to insert (number, percent, or 'auto')

	`height:Object` — height of the image to insert (number, percent, or 'auto')

	`options:Object` (default = `null`) — none supported.

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example inserts a Shape object at the beginning of a text flow:

package flashx.textLayout.edit.examples
{
    import flash.display.Shape;
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.undo.UndoManager;
    
    public class EditManager_insertInlineGraphic
    {
        static public function insertInlineGraphic(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 0, 0 );
            editManager.insertInlineGraphic( createGraphic(), 6, 6, "none" );
            
        }
        static private function createGraphic():Shape
        {
            var shape:Shape = new Shape();
            shape.graphics.beginFill( 0x993366 );
            shape.graphics.drawCircle( 5, 4, 6 );
            return shape;
        }

    }
}

insertText

()

method

public function insertText(text:String, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Inserts text.

Inserts the text at a position or range in the text. If the location supplied in the operationState parameter is a range (or the parameter is null and the current selection is a range), then the text currently in the range is replaced by the inserted text.

Parameters

	`text:String` — the string to insert

	`operationState:SelectionState` (default = `null`) — specifies the text in the flow to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example creates and executes an InsertTextOperation:

 
package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.undo.UndoManager;
    
    public class EditManager_insertText
    {
        static public function insertText(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 4, 4 );
            editManager.insertText( "now " );
        }
    }
}

modifyInlineGraphic

()

method

 public function modifyInlineGraphic(source:Object, width:Object, height:Object, options:Object = null, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Modifies an existing inline graphic.

Set unchanging properties to the values in the original graphic. (Modifying an existing graphic object is typically more efficient than deleting and recreating one.)

Parameters

	`source:Object` — can be either a String interpreted as a uri, a Class interpreted as the class of an Embed DisplayObject, a DisplayObject instance or a URLRequest.

	`width:Object` — new width for the image (number or percent)

	`height:Object` — new height for the image (number or percent)

	`options:Object` (default = `null`) — none supported

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example inserts a circle at the beginning of a text flow, and then changes the width and height properties of the inline graphic to stretch it into an ellipse:

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    import flash.display.Shape;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.undo.UndoManager;
    
    public class EditManager_modifyInlineGraphic
    {
        static public function modifyInlineGraphic(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            editManager.selectRange( 0, 0 );
            editManager.insertInlineGraphic( createGraphic(), 6, 6, "none" );
            
            editManager.selectRange( 0, 1 );
            editManager.modifyInlineGraphic( null, '12', '5', 'none' );
        }
    
        static private function createGraphic():Shape
        {
            var shape:Shape = new Shape();
            shape.graphics.beginFill( 0x993366 );
            shape.graphics.drawCircle( 4, 4, 6 );
            return shape;
        }
    }
}

overwriteText

()

method

public function overwriteText(text:String, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Overwrites the selected text.

If the selection is a point selection, the first character is overwritten by the new text.

Parameters

	`text:String` — the string to insert

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

Example ( How to use this example )

The following example overwrites a string of text in a text flow:

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.elements.TextFlow;
    import flashx.undo.UndoManager;
    
    public class EditManager_overwriteText
    {
        static public function overwriteText(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How zzz brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 4, 6 );
            editManager.overwriteText( "now" ); //Displays: How now brown cow.
        }
    }
}

pasteTextScrap

()

method

 public function pasteTextScrap(scrapToPaste:flashx.textLayout.edit:TextScrap, operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Pastes the TextScrap into the selected area.

If a range of text is specified, the text in the range is deleted.

Parameters

	`scrapToPaste:flashx.textLayout.edit:TextScrap` — the TextScrap to paste

	`operationState:SelectionState` (default = `null`) — specifies the text to which this operation applies; if `null`, the operation applies to the current selection.

See also

flashx.textLayout.edit.IEditManager.cutTextScrap
flashx.textLayout.edit.TextClipboard.getContents
flashx.textLayout.edit.TextScrap

Example ( How to use this example )

The following example cuts a text scrap and pastes it into a different location in a text flow:

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.edit.TextScrap;
    import flashx.textLayout.elements.TextFlow;
    import flashx.undo.UndoManager;
    
    public class EditManager_pasteTextScrap
    {
        static public function pasteText(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How brown cow now.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 13, 17 );
            var scrap:TextScrap = editManager.cutTextScrap();
            
            editManager.selectRange( 3, 3 );
            editManager.pasteTextScrap( scrap ); //Displays: How now brown cow.
        }
    }
}

redo

()

method

public function redo():void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Reperforms the previous undone operation.

Note: If the IUndoManager associated with this IEditManager is also associated with another IEditManager, then it is possible that the redo operation associated with the other IEditManager is the one redone. This can happen if the FlowOperation of another IEditManager is on top of the redo stack.

This function does nothing if undo is not turned on.

See also

flashx.undo.IUndoManager.redo

Example ( How to use this example )

The following example defines a function that reperforms the last undone operation on a text flow:

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_redo
    {
        static public function redo( textFlow:TextFlow ):void
        {
            if( textFlow.interactionManager is IEditManager )
            {
                IEditManager( textFlow.interactionManager ).redo();
            }
        }
    }
}

splitParagraph

()

method

public function splitParagraph(operationState:SelectionState = null):void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Splits the paragraph at the current position.

If a range of text is specified, the text in the range is deleted.

Parameters

operationState:SelectionState (default = null) — specifies the text to which this operation applies; if null, the operation applies to the current selection.

Example ( How to use this example )

The following example splits a paragraph into two:

package flashx.textLayout.edit.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.conversion.TextConverter;
    import flashx.textLayout.edit.EditManager;
    import flashx.textLayout.edit.TextScrap;
    import flashx.textLayout.elements.TextFlow;
    import flashx.undo.UndoManager;
    
    public class EditManager_splitParagraph
    {
        static public function splitParagraph(sprite:Sprite):void
        {
            var textFlow:TextFlow = TextConverter.importToFlow( "How now brown cow.", TextConverter.PLAIN_TEXT_FORMAT );
            textFlow.flowComposer.addController( new ContainerController( sprite ));
            var editManager:EditManager = new EditManager( new UndoManager() );
            textFlow.interactionManager = editManager;
            textFlow.flowComposer.updateAllControllers();
            
            editManager.selectRange( 8, 8 );
            editManager.splitParagraph();    //Displays:     How now
                                            //                brown cow.
        }
    }
}

undo

()

method

public function undo():void

Language Version:

ActionScript 3.0

Runtime Versions:

Flash Player 10, AIR 1.5

Reverses the previous operation.

Note: If the IUndoManager associated with this IEditManager is also associated with another IEditManager, then it is possible that the undo operation associated with the other IEditManager is the one undone. This can happen if the FlowOperation of another IEditManager is on top of the undo stack.

This function does nothing if undo is not turned on.

See also

flashx.undo.IUndoManager.undo

Example ( How to use this example )

The following example defines a function that undoes the last operation on a text flow:

package flashx.textLayout.edit.examples
{
    import flashx.textLayout.edit.IEditManager;
    import flashx.textLayout.elements.TextFlow;
    
    public class EditManager_undo
    {
        static public function undo( textFlow:TextFlow ):void
        {
            if( textFlow.interactionManager is IEditManager )
            {
                IEditManager( textFlow.interactionManager ).undo();
            }
        }
    }
}