The display list object to which the menu is attached. This could be the mouse target (mouseTarget) or one of its ancestors in the display list.

Indicates whether the mouseTarget property was set to null for security reasons. If the nominal value of menuTarget would be a reference to a DisplayObject in another security sandbox, then menuTarget is set to null unless there is permission in both directions across this sandbox boundary. Permission is established by calling Security.allowDomain() from a SWF file, or providing a policy file from the server of an image file, and setting the LoaderContext.checkPolicyFile flag when loading the image.

Related API Elements

The display list object on which the user right-clicked to display the context menu. This could be the display list object to which the menu is attached (contextMenuOwner) or one of its display list descendants.

The value of this property can be null in two circumstances: if there no mouse target, for example when you mouse over something from the background; or there is a mouse target, but it is in a security sandbox to which you don't have access. Use the isMouseTargetInaccessible() property to determine which of these reasons applies.

Related API Elements

Creates an Event object that contains specific information about menu events. Event objects are passed as parameters to event listeners.

Related API Elements

Creates a copy of the ContextMenuEvent object and sets the value of each property to match that of the original.

Returns a string that contains all the properties of the ContextMenuEvent object. The string is in the following format:

[ContextMenuEvent type=value bubbles=value cancelable=value ... contextMenuOwner=value]

Defines the value of the type property of a menuItemSelect event object.

This event has the following properties:

Related API Elements

Defines the value of the type property of a menuSelect event object.

This event has the following properties:

Related API Elements

1. The myContextMenu property is declared and then assigned to a new ContextMenu object and the redRectangle property (of type Sprite) is declared.
2. The removeDefaultItems() method is called. This method removes all built-in context menu items except Print.
3. The addCustomMenuItems() method is called. This method places a Reverse Colors menu item in the defaultItems array by using the push() method of Array. A menuItemSelect event listener is added to the ContextMenuItem object and the associated method is called menuItemSelectHandler(). This method prints some trace() statements whenever the user selects Reverse Colors from the context menu. In addition the red square becomes black and the black text becomes red.
4. Back in the constructor, a menuSelect event listener is added, along with the associated method menuSelectHandler(), which simply prints out three trace() statements every time an item in the context menu is selected.
5. The constructor calls addChildren(), which draws a red square and adds it to the display list, which immediately displays the square.
6. Finally, myContextMenu is assigned to the context menu of the redRectangle property, so that the custom context menu is displayed only when the mouse pointer is over the square.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuEventExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuEventExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}