Gets or sets the name of the field or property in the data associated with the column.

Gets the item renderer for the item that is being edited or the header renderer that is being clicked or resized.

Gets the reason the itemEditEnd event was dispatched. This property is only valid for events of type DataGridEvent.ITEM_EDIT_END.

The possible values are defined in the DataGridEventReason class.

Related API Elements

Creates a new DataGridEvent object with the specified parameters.

Related API Elements

Creates a copy of the DataGridEvent object and sets the value of each property to match the original.

Returns a string that contains all the properties of the DataGridEvent object. The string is in the following format:

[DataGridEvent type=value bubbles=value cancelable=value columnIndex=value rowIndex=value itemRenderer=value dataField=value reason=value]

The DataGridEvent.COLUMN_STRETCH constant defines the value of the type property of a columnStretch event object.

This event has the following properties:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

The DataGridEvent.HEADER_RELEASE constant defines the value of the type property of a headerRelease event object.

This event has the following properties:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

The DataGridEvent.ITEM_EDIT_BEGIN constant defines the value of the type property of an itemEditBegin event object.

This event has the following properties:

Related API Elements

The DataGridEvent.ITEM__EDIT_BEGINNING constant defines the value of the type property of an itemEditBeginning event object.

This event has the following properties:

Related API Elements

The DataGridEvent.ITEM_EDIT_END constant defines the value of the type property of an itemEditEnd event object.

This event has the following properties:

Related API Elements

The DataGridEvent.ITEM_FOCUS_IN constant defines the value of the type property of a itemFocusIn event object.

This event has the following properties:

Related API Elements

The DataGridEvent.ITEM_FOCUS_OUT constant defines the value of the type property of an itemFocusOut event object.

This event has the following properties:

Related API Elements

To run the example, follow these steps:

1. Add the DataGrid component to the library.
2. Save this code as DataGridEventExample.as in the same directory as your FLA file.
3. Set the Document class in the FLA file to DataGridEventExample.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}