Gets or sets a string that indicates how a label is sized and aligned to fit the value of its text property. The following are valid values:

• TextFieldAutoSize.NONE: The label is not resized or aligned to fit the text.
• TextFieldAutoSize.LEFT: The right and bottom sides of the label are resized to fit the text. The left and top sides are not resized.
• TextFieldAutoSize.CENTER: The left and right sides of the label resize to fit the text. The horizontal center of the label stays anchored at its original horizontal center position.
• TextFieldAutoSize.RIGHT: The left and bottom sides of the label are resized to fit the text. The top and right sides are not resized.

The default value is TextFieldAutoSize.NONE.

Related API Elements

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Gets or sets a value that indicates whether extra white space such as spaces and line breaks should be removed from a Label component that contains HTML text. A value of true indicates that white space is to be removed; a value of false indicates that it remains.

The condenseWhite property affects only text that was set by using the htmlText property, not the text property. If you set text by using the text property, the condenseWhite property is ignored.

If you set the condenseWhite property to true, you must use standard HTML commands, such as <br> and <p>, to break the lines of the text in the text field.

The default value is false.

Related API Elements

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Gets or sets the height of the component, in pixels.

Setting this property causes a resize event to be dispatched. See the resize event for detailed information about when it is dispatched.

If the scaleY property of the component is not 1.0, the height of the component that is obtained from its internal coordinates will not match the height value from the parent coordinates. For example, a component that is 100 pixels in height and has a scaleY of 2 has a value of 100 pixels in the parent, but internally stores a value indicating that it is 50 pixels in height.

Related API Elements

Gets or sets the text to be displayed by the Label component, including HTML markup that expresses the styles of that text. You can specify HTML text in this property by using the subset of HTML tags that are supported by the TextField object.

If the default value of the text property is changed in the Property inspector, this changed value takes precedence over any value in the htmlText property field in the Property inspector. To use the htmlText property in the Property inspector, the text property field must contain the value Label, exactly as shown. When coding with ActionScript, you do not need to set the value of the text property; the default value is Label.

The default value is "".

Related API Elements

Gets or sets a value that indicates whether the text can be selected. A value of true indicates that it can be selected; a value of false indicates that it cannot.

Text that can be selected can be copied from the Label component by the user.

The default value is false.

Gets or sets the plain text to be displayed by the Label component.

Note that characters that represent HTML markup have no special meaning in the string and will appear as they were entered.

To display text that contains HTML tags, use the htmlText property. The HTML replaces any text that you set by using the htmlText property, and the text property returns a plain text version of the HTML text, with the HTML tags removed.

If the text property is changed from the default value in the property inspector, it takes precedence over the htmlText property in the property inspector.

The default value is "Label".

Related API Elements

A reference to the internal text field of the Label component.

Gets or sets the width of the component, in pixels.

Setting this property causes a resize event to be dispatched. See the resize event for detailed information about when it is dispatched.

If the scaleX property of the component is not 1.0, the width of the component that is obtained from its internal coordinates will not match the width value from the parent coordinates. For example, a component that is 100 pixels in width and has a scaleX of 2 has a value of 100 pixels in the parent, but internally stores a value indicating that it is 50 pixels wide.

Related API Elements

Gets or sets a value that indicates whether the text field supports word wrapping. A value of true indicates that it does; a value of false indicates that it does not.

The default value is false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Creates a new Label component instance.

Retrieves the default style map for the current component. The style map contains the type that is appropriate for the component, depending on the style that the component uses. For example, the disabledTextFormat style contains a value of null or a TextFormat object. You can use these styles and call setStyle() on the current component. The following code overrides the default disabledTextFormat style on the specified component:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Related API Elements

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Dispatched after there is a change in the width or height of the component.

Note: This event does not occur if you use ActionScript code to change the label text.

This event has the following properties:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Add the Label and Button components to your library.
2. Save this code as LabelExample.as in the same directory as your FLA.
3. Set the DocumentClass in the FLA to LabelExample.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}