Package	org.osmf.elements
Class	public class SerialElement
Inheritance	SerialElement CompositeElement MediaElement EventDispatcher Object

Language Version:

ActionScript 3.0

Product Version:

OSMF 1.0

Runtime Versions:

Flash Player 10, AIR 1.5

SerialElement is a media composition whose elements are presented serially (i.e. in sequence).

The media elements that make up a SerialElement are treated as a single, unified media element. For example, if a SerialElement encapsulates a sequence of videos, the SerialElement will behave as if it's a single VideoElement, but one which plays several videos in sequence.

Typically, a trait on a SerialElement is a reflection of the "current" child of the composition. A SerialElement plays through its children in serial order. As the current child completes its execution, the next child in the sequence becomes the "current" child. To a client of the class, the changes from one current child to the next are hidden. They are only noticeable through changes to the traits of this class.

A childless SerialElement has no notion of a "current" child, so it reflects no traits. The first child that is added to a SerialElement immediately becomes the current child of the composition. If the current child is removed, the next child in the sequence becomes the new current child, if there is a next child. If there is no next child, the first child in the sequence becomes the current child.

The only way that the "current" status can pass from one child to another is when the state of one of the current child's traits changes in such a way that the SerialElement knows that it needs to change its current child. For example, if each child in the sequence has the PlayTrait, the "current" status advances from one child to the next when a child finishes playing and its PlayTrait's PlayState property changes from PLAYING to STOPPED. Another example: if the client of a SerialElement with a SeekTrait seeks from one point to another, the "current" status is likely to change from one child to another.

Here is how each trait is expressed when in serial:

• AudioTrait - The composite trait keeps the audible properties of all children in sync. When the volume of a child element (or the composite element) is changed, the volume is similarly changed for all audible children (and for the composite trait).
• BufferTrait - The composite trait represents the bufferable trait of the current child in the sequence. Any changes apply only to the current child.
• DisplayObjectTrait - The composite trait represents the DisplayObjectTrait of the current child in the sequence.
• DRMTrait - The composite trait represents the DRMTrait of the current child in the sequence.
• DVRTrait - The composite trait represents the DVRTrait of the current child in the sequence.
• DynamicStreamTrait - The composite trait represents the DynamicStreamTrait of the current child in the sequence. Any changes apply only to the current child.
• LoadTrait - The composite trait represents the LoadTrait of the current child in the sequence. Any changes apply only to the current child.
• PlayTrait - The composite trait represents the PlayTrait of the current child in the sequence. Any changes apply only to the current child.
• SeekTrait - The composite trait represents the SeekTrait of the current child in the sequence. A seek operation can change the current child.
• TimeTrait - The composite trait represents a timeline that encapsulates the timeline of all children. Its duration is the sum of the durations of all children. Its position is the sum of the positions of the first N fully complete children, plus the position of the next child.

View the examples

---

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    
    import org.osmf.elements.LightweightVideoElement;
    import org.osmf.elements.SerialElement;
    import org.osmf.media.MediaPlayerSprite;
    import org.osmf.media.URLResource;
    
    public class SerialElementExample extends Sprite
    {
        public function SerialElementExample()
        {
            super();
            
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var mediaPlayerSprite:MediaPlayerSprite = new MediaPlayerSprite();
            var serialElement:SerialElement = new SerialElement();
            
            var videoElement:LightweightVideoElement = new LightweightVideoElement();
            videoElement.resource = new URLResource("http://mediapm.edgesuite.net/strobe/content/test/AFaerysTale_sylviaApostol_640_500_short.flv");
            
            var videoElement2:LightweightVideoElement = new LightweightVideoElement();
            videoElement2.resource = new URLResource("http://mediapm.edgesuite.net/strobe/content/test/elephants_dream_768x428_24_short.flv");
            
            serialElement.addChild(videoElement);
            serialElement.addChild(videoElement2);
            
            addChild(mediaPlayerSprite);
            mediaPlayerSprite.media = serialElement;    
            
        }
    }
}