Package	org.osmf.elements
Class	public class ParallelElement
Inheritance	ParallelElement CompositeElement MediaElement EventDispatcher Object

Language Version:

ActionScript 3.0

Product Version:

OSMF 1.0

Runtime Versions:

Flash Player 10, AIR 1.5

ParallelElement is a media composition whose elements are presented in parallel (concurrently).

The media elements that make up a ParallelElement are treated as a single, unified media element. For example, if a ParallelElement encapsulates a image and a piece of audio, the ParallelElement will behave as if it's a single MediaElement with the audio characteristics of the audio file and the display characteristics of the image file.

Typically, a trait on a ParallelElement is a composite or merged combination of that trait on all its children. When a new media element is added as a child of the media composition, either its traits or the composite's traits are adjusted to make the traits of the media composition and its children consistent.

As an example of the first case, consider AudioTrait. If a client adds a new MediaElement that has its AudioTrait volume at 0.5 to a ParallelElement that has its AudioTrait volume at 0.3, the AudioTrait volume for the child MediaElement is set to 0.3 to be consistent with ParallelElement's trait.

As an example of the second case, consider BufferTrait. If the added MediaElement has a BufferTrait, the ParallelElement's BufferTrait may need to "grow" if the new MediaElement has a larger buffer than any of its other children. In this case, the buffer of the ParallelElement adjusts to the size of its new child.

Here is how each trait is expressed when in parallel:

• AudioTrait - The composite trait keeps the audible properties of all children in sync. When the volume of a child element (or the composite element) is changed, the volume is similarly changed for all audible children (and for the composite trait).
• BufferTrait - The composite trait is buffering if any child is buffering. Its length and size are the length and size of the child with the longest buffer. Its starting position is the minimum (earliest) starting position of all of its children.
• DisplayObjectTrait - If one or more of the composite’s children has the DisplayObjectTrait, the composite trait’s spatial dimensions are defined by the bounding box of the DisplayObject referenced by the displayObject property of the composite's DisplayObjectTrait. If none of the composite’s children has the DisplayObjectTrait, the composite trait's mediaWidth is the width of its widest child and its mediaHeight is the height of its tallest child.
• DRMTrait - The composite trait attempts to keep the DRM state of all children in sync. When a child element is authenticated, all DRM-enabled children are simultaneously authenticated.
• DVRTrait - The composite trait attempts to keep the DVR state of all children in sync.
• DynamicStreamTrait - The composite trait attempts to keep the dynamic streaming state of all children in sync. Specifically, it attempts to keep the autoSwitch property the same for all elements, and the current stream items within a similar bitrate range.
• LoadTrait - The composite trait keeps the load state of all children in sync. When a child element (or the composite element) is loaded, all loadable children (and the composite element) are simultaneously loaded.
• PlayTrait - The composite trait keeps the pause and play states of all children in sync. When a child element (or the composite element) is paused, all pausable children (and the composite element) are simultaneously paused. When a child element (or the composite element) is played, all playable children (and the composite element) are simultaneously played.
• SeekTrait - The composite trait keeps the seek state of all children in sync. When a child element (or the composite element) performs a seek, all seekable children (and the composite element) simultaneously perform that same seek.
• TimeTrait - The composite trait represents a timeline that encapsulates the timelines of all children. Its duration is the maximum of the durations of all children. Its position is kept in sync for all children, with the obvious caveat that a child's position will never be greater than its duration.

View the examples

---

package
{
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    
    import org.osmf.elements.LightweightVideoElement;
    import org.osmf.elements.ParallelElement;
    import org.osmf.elements.VideoElement;
    import org.osmf.layout.LayoutMetadata;
    import org.osmf.layout.LayoutMode;
    import org.osmf.media.MediaPlayer;
    import org.osmf.media.MediaPlayerSprite;
    import org.osmf.media.URLResource;
    
    public class ParallelElementExample extends Sprite
    {
        public function ParallelElementExample()
        {
            super();
            
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var mediaPlayerSprite:MediaPlayerSprite = new MediaPlayerSprite();
            var parallelElement:ParallelElement = new ParallelElement();
                        
            var videoElement:LightweightVideoElement = new LightweightVideoElement();
            videoElement.resource = new URLResource("http://mediapm.edgesuite.net/strobe/content/test/AFaerysTale_sylviaApostol_640_500_short.flv");
            
            var videoElement2:LightweightVideoElement = new LightweightVideoElement();
            videoElement2.resource = new URLResource("http://mediapm.edgesuite.net/strobe/content/test/elephants_dream_768x428_24_short.flv");
                        
            parallelElement.addChild(videoElement);
            parallelElement.addChild(videoElement2);
            
            // Add a vertical layout
            var layout:LayoutMetadata = new LayoutMetadata();
            layout.layoutMode = LayoutMode.VERTICAL;
            parallelElement.addMetadata(LayoutMetadata.LAYOUT_NAMESPACE, layout);            
            
            addChild(mediaPlayerSprite);
            mediaPlayerSprite.media = parallelElement;    
            
        }
    }
}