Whether the CameraRoll.addBitmapData() method is supported. Currently, the feature is only supported in AIR applications on mobile devices.

Reports whether the CameraRoll.browseForImage() method is supported. Currently, the feature is only supported in AIR applications on mobile devices.

Creates a CameraRoll object.

There is only a single media library supported by ActionScript. All CameraRoll objects save to the same image repository.

Adds an image to the device camera roll.

To check at run time whether your application supports the CameraRoll.addBitmapData() method, check the CameraRoll.supportsAddBitmapData property.

Parameters

Opens an image browser dialog to allow the user to select an existing image from the device camera roll.

When the user selects an image, this CameraRoll instance dispatches a select event containing a MediaEvent object. Use the data property of the MediaEvent object to load the image. The data property is a MediaPromise object, which you can load using the loadFilePromise() method of the Loader class. Note that the MediaPromise object contains a valid file object on some platforms (Android and Blackberry Tablet OS), but not on others (iOS). When you use the loadFilePromise() method, the image is loaded properly on all platforms. To access the raw data from the media object, you can open the data source provided by the media promise and read the data using the methods from the IDataInput interface.

To check at run time whether your application supports the CameraRoll.browseForImage() method, check the CameraRoll.supportsBrowseForImage property.

On iOS (and only on the iPad) you can request a specific size for the image browser dialog. You can also specify an area of the screen that you don't want the image browser dialog to cover. This request works only on the iPad, because on that device the image browser does not occupy the entire screen.

To request size and placement options for the image browser (for iPad), pass a CameraRollBrowseOptions object to browseForImage(). With no parameters, this method positions the dialog in the display's top-left corner, using system defaults for the dialog's dimensions.

Parameters

Learn more

Related API Elements

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Dispatched when a user cancels a browse-for-image operation without selecting an image.

This event has the following properties:

Signals that an addBitmapData() operation completed successfully.

This event has the following properties:

The error event is dispatched when an error occurs.

Sources of errors include:

• An image browser cannot be opened.
• An image browser is already in use.
• The AIR application attempts to browse for an image while in the background.
• An image cannot be added to the media library.
• A method is called that is not supported on the device.

This event has the following properties:

Dispatched when a user selects an image from the device media library.

The MediaEvent object dispatched for this event provides access to the chosen media.

Defines the value of the type property of a MediaEvent event object. This event has the following properties: